"SPORK" by Justin Higgins

The story headline is "An Interactive Puzzle".

The story creation year is 2009.

The release number is 4.

The maximum score is 15. 

The story description is "A simple puzzle where you must understand the essence of a spork."

The story genre is "Puzzle".

Every turn, if score is 15, end the game in victory.

The Clearing is a room. "You find yourself in a clearing. It looks
strangely familiar, yet familiarly strange. To the north is an Off-White
House." The clearing contains an openable container called a mailbox.
The mailbox is closed. Inside the mailbox is a letter. The letter is a
thing. The description of the letter is "Welcome to SPORK! The purpose
of this game is simple. You must understand the true essence of a spork.
Only then can you win."

The Off-White House is north of the Clearing. "You find yourself in the
living room of an Off-White house that is in the process of being built.
Or at least it once was. Construction work has seemingly been abandoned
for the time being. To the east is the Workshop. To the west is the
Kitchen. To the north is the Den." The Off-White House contains an
openable transparent container called a trophy case. The trophy case is
closed. There is a note in the trophy case. The description of the note
is "Find the three precious sporks, and put them inside. By doing so,
you will prove that you understand the meaning of the spork."

After inserting a gold spork into the trophy case, award 5 points;

After inserting a silver spork into the trophy case, award 5 points;

After inserting a copper spork into the trophy case, award 5 points;

The Workshop is east of the Off-White House. "You find yourself in the
Workshop, which contains a strange machine. Perhaps you should try
inserting something into it. To the west is the living room of the
Off-White House."

The Kitchen is west of the Off-White House. "You find yourself in a
mostly empty kitchen." A bowl is here. The bowl is an open, unopenable container. The
soup is in the bowl. The indefinite article of the soup is "some". The
description of the bowl is "The bowl of soup is full of some
unidentifiable, thick soup. Perhaps you should eat it." A plate is here.
The plate is an open, unopenable container. The salad is in the plate.
The description of the plate is "The plate of salad is full of some
mostly healthy looking salad."

The ring is a thing. The description of the ring is "It's a nice silver ring."

The penny is a thing. The description of the penny is "It's a 1946 copper penny."

Rule for deciding the concealed possessions of the bowl:
	if the particular possession is a ring and the soup is in the bowl, yes;
	otherwise no.
	
Rule for deciding the concealed possessions of the plate:
	if the particular possession is a penny and the salad is in the plate, yes;
	otherwise no.

Procedural rule while eating:
   ignore the carrying requirements rule.

Instead of taking the soup:
   say "What are you going to do with it? Maybe you should just try eating it?"

Instead of taking the salad:
   say "What are you going to do with it? Maybe you should just try eating it?"

Instead of eating the soup:
	if a spoon is not held by the player:
		say "You don't have the ideal tool for the job. You'd probably think a spork would do the trick, but eating soup with a spork just isn't that pleasant.";
	otherwise:
		say "You eat the delicious soup, and discover a ring at the bottom of the bowl!";
		remove the soup from play;
		now the ring is in the bowl.

Instead of eating the salad:
	if a fork is not held by the player:
		say "You don't have the ideal tool for the job. You may think a spork would do the trick, but eating salad with those little things at the end is hardly pleasant.";
	otherwise:
		say "You eat the delicious salad, and discover a penny at the bottom of the plate!";
		remove the salad from play;
		now the penny is in the plate.
	
The Den is north of the Off-White House. "You find yourself in a dark and disturbing den. Like the rest of the rooms in the house, it is mostly empty. Either someone has moved out, or someone is still waiting to move in." The Den contains an openable container called a cardboard box. The cardboard box is closed. The cardboard box contains a ball.

Understand "cut [something] with [something]" as cutting it with.

Instead of opening the cardboard box:
	If a knife is held by the player,
		try cutting the noun with the knife;
	otherwise say "You're going to need something sharper to cut this box open. You may think a spork would do the trick, but to be honest, the knife edge on a spork is dull and pointless."

Cutting it with is an action applying to two things.

Report cutting it with:
	say "You slash [the noun] with [the second noun], revealing a ball."
	
Carry out cutting a container with something:
	now the noun is open;
	now the noun is unopenable.

Transmutation relates things to each other in groups. The verb to become
(it becomes, they become, it became) implies the transmutation relation.

Definition: a thing is transmutable if it becomes more than one thing.
[* It always becomes itself.]

A thing can be valuable. Something valuable called a spork is in the
Off-White House. It becomes a knife and a spoon and a fork.

A thing can be forklike. The fork is a forklike thing. 

A thing can be spoonlike. The spoon is a spoonlike thing.

A thing can be knifelike. The knife is a knifelike thing.

A thing can be balllike. The ball is a balllike thing. It becomes a gold spork.

A thing can be ringlike. The ring is a ringlike thing. It becomes a silver spork.

A thing can be pennylike. The penny is a pennylike thing. It becomes a copper spork.

A thing can be goldlike. The gold spork is a goldlike thing.

A thing can be silverlike. The silver spork is a silverlike thing.

A thing can be copperlike. The copper spork is a copperlike thing.

The machine is fixed in place in the workshop. The description of the
machine is "It's a strange machine with the words TRANSMUTATOR 3000
written on the side. It has no buttons, only a large opening to insert
objects into." Procedural rule when inserting something into the
machine: ignore the can't insert into what's not a container rule.

Check inserting something which is not transmutable into the machine:
	instead say "You can't transmute that."

Check inserting a gold spork into the machine:
	instead say "You don't want to do that. Seriously."
	
Check inserting a silver spork into the machine:
	instead say "You don't want to do that. Seriously."
	
Check inserting a copper spork into the machine:
	instead say "You don't want to do that. Seriously."
	

To decide which thing is new form of (obj - valuable thing): decide on a random forklike thing which becomes obj.

To decide which thing is new form of (obj - forklike thing): decide on a random spoonlike thing which becomes obj.

To decide which thing is new form of (obj - spoonlike thing): decide on a random knifelike thing which becomes obj.

To decide which thing is new form of (obj - knifelike thing): decide on a random forklike thing which becomes obj.

To decide which thing is new form of (obj - balllike thing): decide on a random goldlike thing which becomes obj.

To decide which thing is new form of (obj - ringlike thing): decide on a random silverlike thing which becomes obj.

To decide which thing is new form of (obj - pennylike thing): decide on a random copperlike thing which becomes obj.

To decide which thing is new form of (obj - goldlike thing): decide on a random goldlike thing which becomes obj.

To decide which thing is new form of (obj - silverlike thing): decide on a random silverlike thing which becomes obj.

To decide which thing is new form of (obj - copperlike thing): decide on a random copperlike thing which becomes obj.

Carry out inserting something into the machine:
	remove the noun from play;
	now the player carries the new form of the noun.

Report inserting something valuable into the machine:
	say "The machine clicks, whirrs, and spits out [a new form of the noun].";
	rule succeeds.

Report inserting something forklike into the machine:
	say "The machine clicks, whirrs, and spits out [a new form of the noun].";
	rule succeeds.

Report inserting something knifelike into the machine:
	say "The machine clicks, whirrs, and spits out [a new form of the noun].";
	rule succeeds.
	
Report inserting something spoonlike into the machine:
	say "The machine clicks, whirrs, and spits out [a new form of the noun].";
	rule succeeds.
	
Report inserting something balllike into the machine:
	say "The machine clicks, whirrs, and with a loud roar, spits out [a new form of the noun].";
	rule succeeds.
	
Report inserting something ringlike into the machine:
	say "The machine clicks, whirrs, and with a loud roar, spits out [a new form of the noun].";
	rule succeeds.
	
Report inserting something pennylike into the machine:
	say "The machine clicks, whirrs, and with a loud roar, spits out [a new form of the noun].";
	rule succeeds.